***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar  22, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJS6602-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2    6.03 
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=40  VTO=1.21  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=2.5e11  gamma=0.5)
Rd     d1    d2    23m TC=4m
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=22  TBV1=7.055e-4 TBV1=5.355e-4  CJO=3.162e-11  M=3.985e-1  VJ=3.909e-1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=2.066e-9  N=1.3008  RS=12.04u  EG=1.0  TT=20n  ;ikf=4.4322e-1)
Rdiode  d1  21    5.4788e-2 TC=1.5m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   2.247e-10
.MODEL     DGD    D(M=5.364e-1   CJO=2.247e-10   VJ=3.905e-1)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.45939e-10
.ENDS
*$
